通用裸机-arm汇编和cpu运行模式

    ldr sp, =0X80200000 /* 设置SVC模式下的栈首地址为0X80200000,大小为2MB */

4.2.2 SPSR

除了 User 和 Sys 这两个模式以外，其他 7 个模式每个都配备了一个专用的物理状态寄存器，叫做 SPSR(备份程序状态寄存器)，当特定的异常中断发生时，SPSR 寄存器用来保存当前程序状态寄存器(CPSR)的值，当异常退出以后可以用 SPSR 中保存的值来恢复 CPSR。User 和 Sys 这两个模式不是异常模式，所以并没有配备 SPSR，因此不能在 User 和Sys 模式下访问 SPSR。

5 CP15协处理器

CP15 协处理器一般用于存储系统管理，但是在中断中也会使用到，比如进入reset复位异常向量时，需要利用协处理器命令进行ICache DCache的开关。CP15 协处理器一共有16 个 32 位寄存器（C0-C15），MRC和MCR用来访问CP15协处理器。

MRC: 将 CP15 协处理器中的寄存器数据读到 ARM 寄存器中。 MCR: 将 ARM 寄存器的数据写入到 CP15 协处理器寄存器中。 格式如下：

MCR{cond} p15, , , , ,

cond:指令执行的条件码，如果忽略的话就表示无条件执行。 opc1：协处理器要执行的操作码。 Rt：ARM 源寄存器，要写入到 CP15 寄存器的数据就保存在此寄存器中。 CRn：CP15 协处理器的目标寄存器。 CRm：协处理器中附加的目标寄存器或者源操作数寄存器，如果不需要附加信息就将CRm 设置为 C0，否则结果不可预测。 opc2：可选的协处理器特定操作码，当不需要的时候要设置为 0

例如：

MRC p15, 0, r0, c0, c0, 0 //将 CP15 中 C0 寄存器的值读取到 R0 寄存器

5.1 c0寄存器（MIDR）

使用 MRC 或者 MCR 指令访问 c0-c15 寄存器的时候，指令中的 CRn、opc1、CRm 和 opc2 通过不同的搭配，其得到的寄存器含义不同：

当CRn=c0，opc1=0，CRm=c0，opc2=0 的时候就表示此时的 c0 就是 MIDR 寄存器，也就是主 ID 寄存器，这个也是 c0 的基本作用。来看下c0作为MDIR寄存器时的含义：

bit31:24：厂商编号，0X41，ARM。 bit23:20：内核架构的主版本号，ARM 内核版本一般使用 rnpn 来表示，比如 r0p1，其中 r0 后面的 0 就是内核架构主版本号。 bit19:16：架构代码，0XF，ARMv7 架构。 bit15:4：内核版本号，0XC07，Cortex-A7 MPCore 内核。 bit3:0：内核架构的次版本号，rnpn 中的 pn，比如 r0p1 中 p1 后面的 1 就是次版本号。

5.2 c1寄存器（SCTLR）

CRn=c1，opc1=0，CRm=c0，opc2=0 的时候就表示此时的 c1 就是 SCTLR 寄存器，也就是系统控制寄存器，这个是 c1 的基本作用。 SCTLR 寄存器主要是完成控制功能的，比如使能或者禁止 MMU、I/D Cache 等。 SCTLR 寄存器展开如下：

bit13：V , 中断向量表基地址选择位，为 0 的话中断向量表基地址为 0X00000000，软件可以使用 VBAR 来重映射此基地址，也就是中断向量表重定位。为 1 的话中断向量表基地址为0XFFFF0000，此基地址不能被重映射。 bit12：I，I Cache 使能位，为 0 的话关闭 I Cache，为 1 的话使能 I Cache。 bit11：Z，分支预测使能位，如果开启 MMU 的话，此位也会使能。 bit10：SW，SWP 和 SWPB 使能位，当为 0 的话关闭 SWP 和 SWPB 指令，当为 1 的时候就使能 SWP 和 SWPB 指令。 bit9:3：未使用，保留。 bit2：C，D Cache 和缓存一致性使能位，为 0 的时候禁止 D Cache 和缓存一致性，为 1 时使能。 bit1：A，内存对齐检查使能位，为 0 的时候关闭内存对齐检查，为 1 的时候使能内存对齐检查。 bit0：M，MMU 使能位，为 0 的时候禁止 MMU，为 1 的时候使能 MMU。 举个读写SCTLR的例子：

MRC p15, 0, , c1, c0, 0 ;读取 SCTLR 寄存器，数据保存到 Rt 中。

MCR p15, 0, , c1, c0, 0 ;将 Rt 中的数据写到 SCTLR(c1)寄存器中。

再来一个关闭MMU,ICache,DCache的例子：

mrc     p15, 0, r0, c1, c0, 0     /* 读取CP15的C1寄存器到R0中                           */

bic     r0,  r0, #(0x1 << 12)     /* 清除C1寄存器的bit12位(I位)，关闭I Cache               */

bic     r0,  r0, #(0x1 <<  2)     /* 清除C1寄存器的bit2(C位)，关闭D Cache                 */

bic     r0,  r0, #0x2             /* 清除C1寄存器的bit1(A位)，关闭对齐                      */

bic     r0,  r0, #(0x1 << 11)     /* 清除C1寄存器的bit11(Z位)，关闭分支预测                   */

bic     r0,  r0, #0x1             /* 清除C1寄存器的bit0(M位)，关闭MMU                     */

mcr     p15, 0, r0, c1, c0, 0     /* 将r0寄存器中的值写入到CP15的C1寄存器中                    */

5.3 c12寄存器（VBAR）

CRn=c12，opc1=0，CRm=c0，opc2=0 的时候就表示此时 c12 为 VBAR 寄存器，也就是中断向量表基地址寄存器。

比如代码链接到DDR的某个位置作为起始地址，起始地址为0X87800000，而中断向量表肯定要放到最前面，也就是 0X87800000 这个地址处。所以就需要设置 VBAR 为 0X87800000，设置命令如下:

dsb

isb

ldr r0, =0x87800000 ; r0=0x87800000

MCR p15, 0, r0, c12, c0, 0 ;将 r0 里面的数据写入到 c12 中，即 c12=0X87800000

dsb

isb

5.3 c15寄存器（CBAR）

CBAR寄存器中保存了GIC（Generic Interrupt Controller）的基地址。GIC基地址偏移0x1000是分发器 block, 偏移0x2000是CPU 接口端 block。

MRC p15, 4, r1, c15, c0, 0 ; 获取 GIC 基础地址，基地址保存在 r1 中

6 参考链接

armv7都是32位处理器，典型的有CorTex-A A7 A8 A9 A15 A17。armv8采用64位处理器，典型的比如手机处理器，有Cortex A53 A76 A77都是64位架构。 https://developer.arm.com/documentation/ddi0406/cd?lang=en

https://developer.arm.com/documentation/den0013/d/?lang=en

https://developer.arm.com/documentation/ddi0464/latest/

7 附件1：armv7裸机启动汇编示例：

.global _start                  /* 全局标号 */

_start:

    ldr pc, =Reset_Handler      /* 复位中断                     */  

    ldr pc, =Undefined_Handler  /* 未定义中断                    */

    ldr pc, =SVC_Handler        /* SVC(Supervisor)中断        */

    ldr pc, =PrefAbort_Handler  /* 预取终止中断                   */

    ldr pc, =DataAbort_Handler  /* 数据终止中断                   */

    ldr pc, =NotUsed_Handler    /* 未使用中断                    */

    ldr pc, =IRQ_Handler        /* IRQ中断                    */

    ldr pc, =FIQ_Handler        /* FIQ(快速中断)未定义中断           */

/* 复位中断 */  

Reset_Handler:

    cpsid i                     /* 关闭全局中断 */

    /* 关闭I,DCache和MMU 

     * 采取读-改-写的方式。

     */

    mrc     p15, 0, r0, c1, c0, 0     /* 读取CP15的C1寄存器到R0中                           */

    bic     r0,  r0, #(0x1 << 12)     /* 清除C1寄存器的bit12位(I位)，关闭I Cache               */

    bic     r0,  r0, #(0x1 <<  2)     /* 清除C1寄存器的bit2(C位)，关闭D Cache                 */

    bic     r0,  r0, #0x2             /* 清除C1寄存器的bit1(A位)，关闭对齐                      */

    bic     r0,  r0, #(0x1 << 11)     /* 清除C1寄存器的bit11(Z位)，关闭分支预测                   */

    bic     r0,  r0, #0x1             /* 清除C1寄存器的bit0(M位)，关闭MMU                     */

    mcr     p15, 0, r0, c1, c0, 0     /* 将r0寄存器中的值写入到CP15的C1寄存器中                    */

#if 0

    /* 汇编版本设置中断向量表偏移 */

    ldr r0, =0X87800000

    dsb

    isb

    mcr p15, 0, r0, c12, c0, 0

    dsb

    isb

#endif

    /* 设置各个模式下的栈指针，

     * 注意：IMX6UL的堆栈是向下增长的！

     * 堆栈指针地址一定要是4字节地址对齐的！！！

     * DDR范围:0X80000000~0X9FFFFFFF

     */

    /* 进入IRQ模式 */

    mrs r0, cpsr

    bic r0, r0, #0x1f   /* 将r0寄存器中的低5位清零，也就是cpsr的M0~M4  */

    orr r0, r0, #0x12   /* r0或上0x13,表示使用IRQ模式                   */

    msr cpsr, r0        /* 将r0 的数据写入到cpsr_c中                    */

    ldr sp, =0x80600000 /* 设置IRQ模式下的栈首地址为0X80600000,大小为2MB */

    /* 进入SYS模式 */

    mrs r0, cpsr

    bic r0, r0, #0x1f   /* 将r0寄存器中的低5位清零，也就是cpsr的M0~M4  */

    orr r0, r0, #0x1f   /* r0或上0x13,表示使用SYS模式                   */

    msr cpsr, r0        /* 将r0 的数据写入到cpsr_c中                    */

    ldr sp, =0x80400000 /* 设置SYS模式下的栈首地址为0X80400000,大小为2MB */

    /* 进入SVC模式 */

    mrs r0, cpsr

    bic r0, r0, #0x1f   /* 将r0寄存器中的低5位清零，也就是cpsr的M0~M4  */

    orr r0, r0, #0x13   /* r0或上0x13,表示使用SVC模式                   */

    msr cpsr, r0        /* 将r0 的数据写入到cpsr_c中                    */

    ldr sp, =0X80200000 /* 设置SVC模式下的栈首地址为0X80200000,大小为2MB */

    cpsie i             /* 打开全局中断 */

#if 0

    /* 使能IRQ中断 */

    mrs r0, cpsr        /* 读取cpsr寄存器值到r0中           */

    bic r0, r0, #0x80   /* 将r0寄存器中bit7清零，也就是CPSR中的I位清零，表示允许IRQ中断 */

    msr cpsr, r0        /* 将r0重新写入到cpsr中            */

#endif

    b main              /* 跳转到main函数                */

/* 未定义中断 */

Undefined_Handler:

    ldr r0, =Undefined_Handler

    bx r0

/* SVC中断 */

SVC_Handler:

    ldr r0, =SVC_Handler

    bx r0

/* 预取终止中断 */

PrefAbort_Handler:

    ldr r0, =PrefAbort_Handler  

    bx r0

/* 数据终止中断 */

DataAbort_Handler:

    ldr r0, =DataAbort_Handler

    bx r0

/* 未使用的中断 */

NotUsed_Handler:

    ldr r0, =NotUsed_Handler

    bx r0

IRQ_Handler:

    push {lr}                   /* 保存lr地址 */

    push {r0-r3, r12}           /* 保存r0-r3，r12寄存器 */

    mrs r0, spsr                /* 读取spsr寄存器 */

    push {r0}                   /* 保存spsr寄存器 */

    mrc p15, 4, r1, c15, c0, 0 /* 从CP15的C0寄存器内的值到R1寄存器中