电脑数字钟硬件原理图

2014-04-09 13:47:49来源: 互联网

电脑数字钟硬件原理图

为了节约制作硬件的开支,我们利用单片机开发机上的硬件资源,开发了电脑数字钟的软件。该数字钟由8031单片机控制,采用24小时制计时,利用开发机上的六个LED显示器来显示时、分和秒,使用P1端口中的P1.0端口线实现整点报时功能;使用P3端口的P3.0实现闹钟功能。其硬件原理图如图一所示。

图中按键K1,K2,K3及开关K5,K6的定义如下表所示

图中的开关K4用于闹钟控制,当K4=1时(开关处于ON的位置),打开闹钟,使之在预定时间起闹;当K1=0时(开关处于OFF的位置),则关闭闹钟,使之不闹。另外,在闹钟响起时,K4也可作为止闹开关使用,若不止闹,则闹一分钟。闹钟信号用发光二极管来模拟。
整点报时信号也是用发光二极管来模拟的。当整点时,P1.0口所接的发光二极管点亮一分钟。
电脑数字钟的秒信号是利用8031单片机定时器T0产生的。由于开发机的晶振频率为6MHz,使得T0的最大定时时间远远小于1秒,因此,在设计时采用了硬件计数与软件计数相结合的方式,即通过T0产生一定的定时时间,然后再利用软件进行计数,从而产生1秒钟的时间信号。在设计中,定时器T0采用了中断方式。当定时时间到时,单片机产生中断,在T0的中断服务程序中实现时、分、秒的累加。并且,该中断的优先级别高于其它中断,因此,保证了电子钟走时准确。在设计中,利用外部中断0和外部中断1分别作为校时和闹钟校时按键的触发输入。当需要校时时,拨动K5或K6开关,便产生外部中断,进入相应的中断服务程序。在外部中断0和外部中断1的中断服务程序中,都只有一条"表示有按键"的标志位置1的指令,然后在主程序中用查询标志位的方式判断是否有键按下。若查得标志位为1则进入校时子程序进行校时的相应处理;若为0则照常进行时间显示。当拨动K5开关时,进入校时状态,用户可以方便地校准时间。当拨动K6开关时,便进入闹钟校时状态,这时,可根据需要设置起闹时间。在闹钟校时期间,时钟继续计数,即闹钟校时不影响时钟走时。 


摘 要:介绍了用8031单片机控制的电脑数字钟的硬件结构与软件设计。给出了汇编
语言源程序。 
关键词:单片机,实时控制,数字钟,中断 
数字电子钟的设计方法有多种,例如,可用中小规模集成电路组成电子钟;也可以利用专用的电子钟芯片配以显示电路及其所需要的外围电路组成电子钟;还可以利用单片机来实现电子钟等等。这些方法都各有特点,其中,利用单片机实现的电子钟具有编程灵活,便于电子钟功能的扩充,即可用该电子钟发出各种控制信号,精确度高等特点。
所设计的电子钟有以下功能:
1. 24小时制时间显示。
2. 可随时进行时间校对。 
3. 整点报时。
4. 闹钟功能。
为了节约制作硬件的开支,我们利用单片机开发机上的硬件资源,开发了电脑数字钟的软件。该数字钟由8031单片机控制,采用24小时制计时,利用开发机上的六个LED显示器来显示时、分和秒,使用P1端口中的P1.0端口线实现整点报时功能;使用P3端口的P3.0实现闹钟功能。其硬件原理图如图一所示。


图一 电脑数字钟硬件原理图

图中按键K1,K2,K3及开关K5,K6的定义如下表所示
 
图中的开关K4用于闹钟控制,当K4=1时(开关处于ON的位置),打开闹钟,使之在预定时间起闹;当K1=0时(开关处于OFF的位置),则关闭闹钟,使之不闹。另外,在闹钟响起时,K4也可作为止闹开关使用,若不止闹,则闹一分钟。闹钟信号用发光二极管来模拟。
整点报时信号也是用发光二极管来模拟的。当整点时,P1.0口所接的发光二极管点亮一分钟。
电脑数字钟的秒信号是利用8031单片机定时器T0产生的。由于开发机的晶振频率为6MHz,使得T0的最大定时时间远远小于1秒,因此,在设计时采用了硬件计数与软件计数相结合的方式,即通过T0产生一定的定时时间,然后再利用软件进行计数,从而产生1秒钟的时间信号。在设计中,定时器T0采用了中断方式。当定时时间到时,单片机产生中断,在T0的中断服务程序中实现时、分、秒的累加。并且,该中断的优先级别高于其它中断,因此,保证了电子钟走时准确。在设计中,利用外部中断0和外部中断1分别作为校时和闹钟校时按键的触发输入。当需要校时时,拨动K5或K6开关,便产生外部中断,进入相应的中断服务程序。在外部中断0和外部中断1的中断服务程序中,都只有一条"表示有按键"的标志位置1的指令,然后在主程序中用查询标志位的方式判断是否有键按下。若查得标志位为1则进入校时子程序进行校时的相应处理;若为0则照常进行时间显示。当拨动K5开关时,进入校时状态,用户可以方便地校准时间。当拨动K6开关时,便进入闹钟校时状态,这时,可根据需要设置起闹时间。在闹钟校时期间,时钟继续计数,即闹钟校时不影响时钟走时。 
程序中的一些存储单元的定义如下:
  20H~22H:时、分、秒单元
  40H~42H:校时或闹钟校时期间的时、分、秒单元
  50H~51H:起闹时间的时、分单元
  79H~7EH:显示缓冲区
用户标志位F0:校时标志,当F0=1时,表示校时
    位7FH:闹钟校时标志,当7FH=1时,表示闹钟校时
    以上的总体设计使得电脑数字钟的精确度较高,因为在程序的执行过程中,任何指令都不影响定时器的正常计数。从而,使数字钟的精度仅仅取决于单片机的产生机器周期电路和定时器T0硬件电路的精确度。另外,程序较为简洁,具有可靠性和较好的可读性。
我们设计电脑数字钟的目的并不在于电脑数字钟本身,而是想将它的设计应用于实时控制之中。只要对上述程序和硬件电路稍加修改,便可以得到实时控制的实用系统,从而应用到实际工作与生产中去。
电脑数字钟的汇编语言源程序如下所示:
ORG 0000H
LJMP MAIN
ORG 0003H
SETB PSW.5
RETI
ORG 000BH
LJMP CLOCK
ORG 0013H
SETB 7FH
RETI
ORG 0030H
MAIN: MOV SP,#60H
MOV TMOD,#01H
MOV IE,#87H
SETB PT0
MOV TL0,#0B7H
MOV TH0,#3CH
MOV 20H,#00H
MOV 21H,#00H
MOV 22H,#00H
MOV 23H,#00H
MOV 50H,#06H
MOV 51H,#28H
MOV 52H,#00H
CLR PSW.5
CLR 7FH
SETB TR0
SETB IT0
SETB IT1
CLR P3.0
SS: LCALL CUTIN0
LCALL SSCAN
JNB PSW.5,LK
LCALL KEY0
LK: JNB 7FH,SS
LCALL KEY1
SJMP SS
CUTIN0: PUSH PSW
PUSH ACC
MOV 25H,R0
MOV R0,#79H
MOV A,22H
ACALL BCD
MOV A,21H
ACALL BCD
MOV A,20H
ACALL BCD
MOV R0,25H
POP ACC
POP PSW
RET
CUTIN1: PUSH PSW
PUSH ACC
MOV 25H,R0
MOV R0,#79H
MOV A,42H
ACALL BCD
MOV A,41H
ACALL BCD
MOV A,40H
ACALL BCD
MOV R0,25H
POP ACC
POP PSW
RET
BCD: MOV B,#0AH
DIV AB
MOV @R0,B
INC R0
MOV @R0,A
INC R0
RET
CLOCK: JNB PSW.5,ZC
LJMP FH
ZC: MOV TL0,#0B7H
MOV TH0,#3CH
PUSH PSW
PUSH ACC
INC 23H
MOV A,23H
CJNE A,#0AH,RET0
MOV 23H,#00H
INC 22H
MOV A,22H
CJNE A,#3CH,RET0
MOV 22H,#00H
SETB P1.0
CLR P3.0
INC 21H
MOV A,21H
CJNE A,#3CH,RET0
MOV 21H,#00H
CLR P1.0
INC 20H
MOV A,20H
CJNE A,#18H,RET0
MOV 20H,#00H
AJMP RET0
RET0: MOV A,21H
CJNE A,51H,B0
MOV A,20H
CJNE A,50H,B0
SETB P3.0
B0: POP ACC
POP PSW
FH: RETI
SSCAN: MOV R6,#05H
SS2: MOV 30H,#20H
MOV 31H,#7EH
MOV R7,#06H
SS1: MOV R1,#21H
MOV A,30H
MOVX @R1,A
MOV R0,31H
MOV A,@R0
MOV DPTR,#SC
MOVC A,@A+DPTR
MOV R1,#22H
MOVX @R1,A
LCALL D1
MOV A,30H
RR A
MOV 30H,A
DEC 31H
DJNZ R7,SS1
DJNZ R6,SS2
RET
SC: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
KEY: MOV 42H,#00H
A0: MOV P1,#0FFH
MOV A,P1
ANL A,#38H
MOV R3,A
LCALL DELAY
MOV P1,#0FFH
MOV A,P1
ANL A,#38H
CLR C
SUBB A,R3
JNZ A0
MOV A,R3
CJNE A,#38H,A00
SJMP A0
A00: CJNE A,#30H,TOK2
INC 41H
MOV R2,41H
CJNE R2,#3CH,A1
MOV 41H,#00H
A1: MOV P1,#0FFH
MOV A,P1
ANL A,#08H
JNZ A0
LCALL DELAY
SJMP A1
TOK2: CJNE A,#28H,TOK3
DEC 41H
MOV R2,41H
CJNE R2,#0FFH,A2
MOV 41H,#3BH
A2: MOV P1,#0FFH
MOV A,P1
ANL A,#10H
JNZ A0
LCALL DELAY
SJMP A2
TOK3: CJNE A,#18H,A0
AA: MOV P1,#0FFH
MOV A,P1
ANL A,#20H
JNZ A3
LCALL DELAY
SJMP AA
A3: MOV P1,#0FFH
MOV A,P1
ANL A,#38H
MOV R3,A
LCALL DELAY
MOV P1,#0FFH
MOV A,P1
ANL A,#38H
CLR C
SUBB A,R3
JNZ A3
MOV A,R3
CJNE A,#38H,A33
SJMP A3
A33: CJNE A,#30H,TO2
INC 40H
MOV R2,40H
CJNE R2,#18H,A4
MOV 40H,#00H
A4: MOV P1,#0FFH
MOV A,P1
ANL A,#08H
JNZ A3
LCALL DELAY
SJMP A4
TO2: CJNE A,#28H,TO3
DEC 40H
MOV R2,40H
CJNE R2,#0FFH,A5
MOV 40H,#17H
A5: MOV P1,#0FFH
MOV A,P1
ANL A,#10H
JNZ A3
LCALL DELAY
SJMP A5
TO3: CJNE A,#18H,A3
RET
KEY0: MOV 41H,21H
MOV 40H,20H
CLR TR0
ACALL KEY
CLR PSW.5
MOV 22H,42H
MOV 21H,41H
MOV 20H,40H
MOV TL0,#0B7H
MOV TH0,#3CH
SETB TR0
RET
KEY1: MOV 41H,51H
MOV 40H,50H
LCALL KEY
CLR 7FH
MOV 51H,41H
MOV 50H,40H
RET
D1: MOV R4,#02H
D11: MOV R5,#0FFH
DJNZ R5,$
DJNZ R4,D11
RET
DELAY: PUSH ACC
LCALL CUTIN1
LCALL SSCAN
POP ACC
RET

关键字:电脑  数字钟硬件  原理图

编辑:神话 引用地址:http://www.eeworld.com.cn/mndz/2014/0409/article_25358.html
本网站转载的所有的文章、图片、音频视频文件等资料的版权归版权所有人所有,本站采用的非本站原创文章及图片等内容无法一一联系确认版权者。如果本网所选内容的文章作者及编辑认为其作品不宜公开自由传播,或不应无偿使用,请及时通过电子邮件或电话通知我们,以迅速采取适当措施,避免给双方造成不必要的经济损失。
论坛活动 E手掌握
微信扫一扫加关注
论坛活动 E手掌握
芯片资讯 锐利解读
微信扫一扫加关注
芯片资讯 锐利解读
推荐阅读
全部
电脑
数字钟硬件
原理图

小广播

独家专题更多

TTI携TE传感器样片与你相见,一起传感未来
TTI携TE传感器样片与你相见,一起传感未来
TTI携TE传感器样片与你相见,一起传感未来
富士通铁电随机存储器FRAM主题展馆
富士通铁电随机存储器FRAM主题展馆
馆内包含了 纵览FRAM、独立FRAM存储器专区、FRAM内置LSI专区三大部分内容。 
走,跟Molex一起去看《中国电子消费品趋势》!
走,跟Molex一起去看《中国电子消费品趋势》!
 
电子工程世界版权所有 京ICP证060456号 京ICP备10001474号 电信业务审批[2006]字第258号函 京公海网安备110108001534 Copyright © 2005-2016 EEWORLD.com.cn, Inc. All rights reserved