单片机经典实验实例精华详解(附源程序) (四)

2013-05-26 13:37:33来源: 互联网
四、单片机倒计时定时器

  这里我们先要安装好51试验板上的两个轻触按钮开关,我们采用的是独立式按钮开关,也就是说将开关直接连接到电源的地和单片机的对应引脚之间,这里K1接到单片机的P3.6引脚,K2接到P3.7。正常情况下单片机的P3.6、P3.7都被程序初始化时置“1” 当有按键按下时对应的单片机引脚被按钮开关下拉为“0”,这种方法比较直观,而且比较简单,在按键数量不多的场合下使用很广泛。

  

  因为机械开关开关时有抖动,所以需要在程序中加一个软件去抖动程序,它的工作原理如下:当单片机检测到有按键被按下后立即执行一个10毫秒的延时程序,然后再在检测该引脚是否仍然为闭合状态?如果仍然为闭合说明确认该键被按下立即执行相应的处理程序,否则可能是干扰,丢弃这次检测结果。

  接下来我们再安装一个四位的拨码开关,就是图中红色的开关,它相当于四个装在一起的拨动开关,当开关拨到“ON”一侧时,对应的那路就会接通,反之断开。它在单片机中一般用于设置初始参数,而且不经常改变的场合。这里因为单片机引脚资源不够,所以我们只使用了拨码开关的第2、3、4位,第1位闲置。三个开关可以逻辑组合出8种状态,所以我们能够方便灵活地预置多达7种的倒计时时间。

  最后我们来安装两个继电器和相关电路,有了继电器我们的实验板不再仅仅是做做实验而已,可以用于控制一些负载,比如说:充电器,洗衣机,电风扇等,使我们的实验板的实用功能大大增强,这也是电子制作实验室网站的单片机实验板和其他公司的产品不同的地方。

  

  这里继电器由相应的S8050三极管来驱动,开机时,单片机初始化后的P2.3/P2.4为高电平,+5伏电源通过电阻使三极管导通,所以开机后继电器始终处于吸合状态,如果我们在程序中给单片机一条:CLR P2.3或者CLR P2.4的指令的话,相应三极管的基极就会被拉低到零伏左右,使相应的三极管截至,继电器就会断电释放,每个继电器都有一个常开转常闭的接点,便于在其他电路中使用,继电器线圈两端反相并联的二极管是起到吸收反向电动势的功能,保护相应的驱动三极管,这种继电器驱动方式硬件结构比较简单。

  ;电子制作实验室http://www.xie-gang.com/

  ;可设定时间的倒计时定时器,可选择5/15/20/30/35/45/50分钟倒计时

  ;倒计时时间由四位拨码开关的2/3/4位来控制,

  ;第2位表示5分钟,第3位表示15分钟,第4位表示30分钟,

  ;通过不同的组合可以产生5/15/20/30/35/45/50分钟倒计时

  ;P1.0口的外接的发光二极管为状态LED,定时未开始时LED常亮,定时过程中LED闪烁

  ;K1为开始按钮,K2为停止按钮

  a_bit equ 20h ;数码管个位数存放内存位置

  b_bit equ 21h ;数码管十位数存放内存位置

  temp equ 22h ;计数器数值存放内存位置

  ;开机初始化

  MOV P3,#0FFH;对P3口初始化,设置为高电平,用于按键输入

  MOV P0,#0FFH;使显示时间数码管熄灭

  CLR P1.0;点亮LED指示灯

  ;等待键盘输入

  START:JB P3.6,$;循环判断开始按钮K1是否按下?

  ACALL DELAY10;延时10毫秒触点消抖

  JB P3.6,START;如果是干扰就返回

  JNB P3.6,$;等待按键松开

  ;读拨码开关的状态,获得倒计时时间

  SET:MOV A,#0;首先对A清零

  JB P2.0,A1;判断拨码开关的第2位是否接通,接通就对A加5

  ADD A,#5

  A1:JB P2.1,A2;判断拨码开关的第3位是否接通,接通就对A加15

  ADD A,#15

  A2:JB P2.2,A3;判断拨码开关的第4位是否接通,接通就对A加30

  ADD A,#30

  A3:MOV TEMP,A

  ;这时TEMP中的值就是倒计时时间

  ;数码管显示定时时间的程序

  display:CLR P2.4;使继电器1释放,开始定时(开机时继电器处于吸合状态)

  CLR P2.3;使继电器2释放,开始定时(开机时继电器处于吸合状态)

  MOV R2,#120

  AB:MOV R3,#250

  TIME1:mov a,temp ;将temp中的十六进制数转换成10进制

  mov b,#10 ;10进制/10=10进制

  div ab

  mov b_bit,a ;十位在a

  mov a_bit,b ;个位在b

  mov dptr,#numtab ;指定查表启始地址

  mov r0,#4

  dpl1: mov r1,#250 ;

  dplop: mov a,a_bit ;取个位数

  MOVC A,@A+DPTR ;查个位数的7段代码

  mov p0,a ;送出个位的7段代码

  clr p2.7 ;开个位显示

  ACALL DELY1;显示1毫秒

  setb p2.7;关闭个位显示,防止鬼影

  mov a,b_bit ;取十位数

  MOVC A,@A+DPTR ;查十位数的7段代码

  mov p0,a ;送出十位的7段代码

  clr p2.6 ;开十位显示

  ACALL DELY1;显示1毫秒

  setb p2.6;关闭十位显示,防止鬼影

  ;插入一段判断定时过程中是否有按键输入的程序段

  C1:JB P3.6,B1

  ACALL DELAY10;延时10毫秒消抖

  JB P3.6,C1

  JNB P3.6,$;等待按键松开

  AJMP SET

  B1:JB P3.7,M33

  ACALL DELAY10;延时10毫秒消抖

  JB P3.7,B1

  JNB P3.7,$;等待按键松开

  AJMP OVER

  M33:djnz r3,TIME1 ;2毫秒循环执行250次,时间约0.5秒

  CPL P1.0;使LED每1秒闪烁一次

  djnz r2,AB ;循环执行120次,时间为1分钟

  DEC TEMP;满一分钟对定时时间减1

  MOV A,TEMP

  JNZ DISPLAY;判断TEMP的数值是否为0?不为0循环

  ;结束定时

  OVER:CLR P1.0;LED指示灯常亮

  SETB P2.4;继电器1吸合,定时结束,退回到开机时的状态

  SETB P2.3;继电器2吸合,定时结束,退回到开机时的状态

  AJMP START;退到开机初始化状态

  ;1毫秒延时子程序

  DELY1:MOV R4,#2

  D1:MOV R5,#248

  DJNZ R5,$

  DJNZ R4,D1

  RET

  ;10毫秒延时子程序

  DELAY10:MOV R4,#20

  D2:MOV R5,#248

  DJNZ R5,$

  DJNZ R4,D2

  RET

  ;实验板上的7段数码管0~9数字的共阴显示代码

  numtab: DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH

  end

关键字:单片机  经典实验  实例精华

编辑:神话 引用地址:http://www.eeworld.com.cn/mndz/2013/0526/article_18680.html
本网站转载的所有的文章、图片、音频视频文件等资料的版权归版权所有人所有,本站采用的非本站原创文章及图片等内容无法一一联系确认版权者。如果本网所选内容的文章作者及编辑认为其作品不宜公开自由传播,或不应无偿使用,请及时通过电子邮件或电话通知我们,以迅速采取适当措施,避免给双方造成不必要的经济损失。
论坛活动 E手掌握
微信扫一扫加关注
论坛活动 E手掌握
芯片资讯 锐利解读
微信扫一扫加关注
芯片资讯 锐利解读
推荐阅读
全部
单片机
经典实验
实例精华

小广播

独家专题更多

TTI携TE传感器样片与你相见,一起传感未来
TTI携TE传感器样片与你相见,一起传感未来
TTI携TE传感器样片与你相见,一起传感未来
富士通铁电随机存储器FRAM主题展馆
富士通铁电随机存储器FRAM主题展馆
馆内包含了 纵览FRAM、独立FRAM存储器专区、FRAM内置LSI专区三大部分内容。 
走,跟Molex一起去看《中国电子消费品趋势》!
走,跟Molex一起去看《中国电子消费品趋势》!
 
电子工程世界版权所有 京ICP证060456号 京ICP备10001474号 电信业务审批[2006]字第258号函 京公海网安备110108001534 Copyright © 2005-2016 EEWORLD.com.cn, Inc. All rights reserved